SUBROUTINE EZFFTI(N,WSAVE)   
C***BEGIN PROLOGUE  EZFFTI    
C***DATE WRITTEN   790601   (YYMMDD)    
C***REVISION DATE  860115   (YYMMDD)    
C***CATEGORY NO.  J1A1   
C***KEYWORDS  FOURIER TRANSFORM    
C***AUTHOR  SWARZTRAUBER, P. N., (NCAR) 
C***PURPOSE  Initialize EZFFTF and EZFFTB    
C***DESCRIPTION
C    
C  Subroutine EZFFTI initializes the array WSAVE which is used in
C  both EZFFTF and EZFFTB.  The prime factorization of N together with
C  a tabulation of the trigonometric functions are computed and  
C  stored in WSAVE. 
C    
C  Input Parameter  
C    
C  N       the length of the sequence to be transformed.    
C    
C  Output Parameter 
C    
C  WSAVE   a work array which must be dimensioned at least 3*N+15.    
C          The same work array can be used for both EZFFTF and EZFFTB 
C          as long as N remains unchanged.  Different WSAVE arrays    
C          are required for different values of N.
C***REFERENCES  (NONE)   
C***ROUTINES CALLED  EZFFT1   
C***END PROLOGUE  EZFFTI 
      DIMENSION       WSAVE(*)
C***FIRST EXECUTABLE STATEMENT  EZFFTI  
      IF (N .EQ. 1) RETURN    
      CALL EZFFT1 (N,WSAVE(2*N+1),WSAVE(3*N+1))   
      RETURN   
      END 
      SUBROUTINE EZFFT1(N,WA,IFAC) 
C***BEGIN PROLOGUE  EZFFT1    
C***REFER TO  EZFFTI
C***ROUTINES CALLED  (NONE)   
C***END PROLOGUE  EZFFT1 
      DIMENSION       WA(*)      ,IFAC(*)    ,NTRYH(4) 
      DATA NTRYH(1),NTRYH(2),NTRYH(3),NTRYH(4)/4,2,3,5/
C***FIRST EXECUTABLE STATEMENT  EZFFT1  
      TPI = 8.*ATAN(1.)  
      NL = N   
      NF = 0   
      J = 0    
  101 J = J+1  
      IF (J-4) 102,102,103    
  102 NTRY = NTRYH(J)    
      GO TO 104
  103 NTRY = NTRY+2 
  104 NQ = NL/NTRY  
      NR = NL-NTRY*NQ    
      IF (NR) 101,105,101
  105 NF = NF+1
      IFAC(NF+2) = NTRY  
      NL = NQ  
      IF (NTRY .NE. 2) GO TO 107   
      IF (NF .EQ. 1) GO TO 107
      DO 106 I=2,NF 
         IB = NF-I+2
         IFAC(IB+2) = IFAC(IB+1)   
  106 CONTINUE 
      IFAC(3) = 2   
  107 IF (NL .NE. 1) GO TO 104
      IFAC(1) = N   
      IFAC(2) = NF  
      ARGH = TPI/REAL(N) 
      IS = 0   
      NFM1 = NF-1   
      L1 = 1   
      IF (NFM1 .EQ. 0) RETURN 
      DO 111 K1=1,NFM1   
         IP = IFAC(K1+2) 
         L2 = L1*IP 
         IDO = N/L2 
         IPM = IP-1 
         ARG1 = REAL(L1)*ARGH 
         CH1 = 1.   
         SH1 = 0.   
         DCH1 = COS(ARG1)
         DSH1 = SIN(ARG1)
         DO 110 J=1,IPM  
            CH1H = DCH1*CH1-DSH1*SH1    
            SH1 = DCH1*SH1+DSH1*CH1
            CH1 = CH1H   
            I = IS+2
            WA(I-1) = CH1
            WA(I) = SH1  
            IF (IDO .LT. 5) GO TO 109   
            DO 108 II=5,IDO,2 
               I = I+2   
               WA(I-1) = CH1*WA(I-3)-SH1*WA(I-2)  
               WA(I) = CH1*WA(I-2)+SH1*WA(I-3)    
  108       CONTINUE
  109       IS = IS+IDO  
  110    CONTINUE   
         L1 = L2    
  111 CONTINUE 
      RETURN   
      END